3.9. adminstall.cfg

NOTA. Se aplica solo al sistema "1C:Enterprise" bajo el sistema operativo Windows.

El archivo adminstall.cfg indica que el sistema de programas "1C:Enterprise" se instaló con las herramientas de administración del sistema operativo Windows. El archivo se encuentra en el directorio de archivos de configuración del sistema "1C:Enterprise" y es un documento de texto codificado en UTF-8.

El archivo puede contener una sola línea que define la variante de instalación:

AdmInstall=<Mode>

<Mode>

Describe el modo de instalación:

Logon - la instalación se realizó mediante un script de inicio de sesión durante el inicio de sesión del usuario en el dominio.
Restart - la instalación se realizó mediante políticas de grupo.

A continuación se muestra un ejemplo de un script de instalación que se puede usar para instalar el sistema "1C:Enterprise" usando las herramientas administrativas del sistema operativo Windows.

Option Explicit

' Modificar la interfaz de usuario
Const msiUILevelNoChange = 0
' Utilizar la interfaz de usuario predeterminada
Const msiUILevelDefault = 1
' No mostrar la interfaz de usuario (configuración silenciosa)
Const msiUILevelNone = 2
' Solo barra de progreso y visualización de error
Const msiUILevelBasic = 3
' Interfaz de usuario sin mensajes de diálogo
Const msiUILevelReduced = 4
' Interfaz de usuario completa
Const msiUILevelFull = 5
' Si se utiliza con msiUILevelBasic, se muestra el indicador
' Progreso sin botón Cancel
Const msiUILevelHideCancel = 32
' Si se utiliza con msiUILevelBasic, se muestra el indicador
' progreso sin mostrar ningún cuadro de diálogo, incluidos los errores.
Const msiUILevelProgressOnly = 64
' Si se utiliza con cualquiera de los valores enumerados, el instalador
' muestra un mensaje al final de la instalación sobre el resultado final.
Const msiUILevelEndDialog = 128

'***** Debe cambiarse al directorio de instalación real
Const DistrFolder="\\Server\1CDistr\"

Const shortName = "Lanzar 1C Enterprise"
Dim shortcutTarget : shortcutTarget = DistrFolder & "1cestart.exe"

' Constantes para determinar la acción
' instalación requerida
Const requiredInstall = 1
' borrado requerido
Const requiredUninstall = 0

' Valor del parámetro ProductCode del archivo setup.ini...
'... para la versión eliminada
Const unInstallUID="{9173B91C-FF56-4F25-82D1-7F68244044CD}"
'... para la versión instalada
Const InstallUID="{0BC98727-04AD-470F-9EEE-0162C543833F}"

' procedimiento para instalar o desinstalar la versión específica del producto
Sub installOrUninstall (ByVal productCode, ByVal msiPackage, ByVal mstTransform, ByVal requiredAction)
' productCode - Información sobre el código del producto. Se encuentra en el archivo
' setup.ini, clave ProductCode
' msiPackage - paquete de distribución de 1CEnterprise
' mstTransform: archivo de conversión de idioma para el instalador
' requiredAction - se requiere la acción requiredInstall o
' requiredUninstall

' Variable para formar parámetros
' adicionales al instalador
Dim cmdLine

On Error Resume Next

Dim installer, session

Set installer = Nothing
Set session = Nothing
Set installer = Wscript.CreateObject("WindowsInstaller.Installer") : processError
installer.UILevel = msiUILevelBasic 'msiUILevelNone 'o especifique otra variante de interfaz de usuario
' comprobación de la instalación del producto
Set session = installer.OpenProduct(productCode)

If session Is Nothing AND requiredAction = requiredInstall Then
' el producto no está instalado y es necesario instalarlo
cmdLine = "TRANSFORMS=adminstallrelogon.mst;"
If Not mstTransform Is Empty Then
' añadimos instrucciones al instalador para hablar en el idioma especificado
cmdLine = cmdLine & mstTransform
' opcionalmente se puede especificar qué componentes instalar
'cmdLine = cmdLine & " DesignerALLCLIENTS=1 THINCLIENT=1 WEBSERVEREXT=0 SERVER=0 CONFREPOSSERVER=0 CONVERTER77=0 SERVERCLIENT=1 LANGUAGES=ES"
End If
' instalaremos la plataforma
Set session = installer.InstallProduct(msiPackage, cmdLine) : processError
' crearemos un acceso directo en el escritorio
createShurtcut()

ElseIf Not session Is Nothing AND requiredAction = requiredUninstall Then
' la plataforma ya está instalada y necesita ser eliminada
' ¡Solo puede haber un objeto session!
Set session = Nothing
'indicaremos que debe eliminar esta versión del ordenador del usuario
 cmdLine = "REMOVE=ALL"
' eliminamos
Set session = installer.InstallProduct(msiPackage, cmdLine) : processError
End If

Set session = Nothing
Set installer = Nothing

End Sub


'procesamiento de errores
Sub processError
Dim msg
If Err = 0 Then Exit Sub
msg = Err.Source & " " & Hex(Err) & ": " & Err.Description
Wscript.Echo msg
Wscript.Quit 2
End Sub

'creación de un acceso directo
Sub createShurtcut
Dim WshShell, oShellLink
Set WshShell = WScript.CreateObject("WScript.Shell")
Dim strDesktop : strDesktop = WshShell.SpecialFolders("Desktop")
Set oShellLink = WshShell.CreateShortcut(strDesktop & "\" & shortcutName & ".lnk")
oShellLink.TargetPath = shortcutTarget
oShellLink.WindowStyle = 1
oShellLink.Description = shortcutName
oShellLink.Save
Set oShellLink = Nothing
Set WshShell = Nothing
End Sub

' eliminamos la versión 260
installOrUninstall unInstallUID, DistrFolder + "8.2.9.260\setup\1CEnterprise 8.2.msi", "1049.mst", requiredUninstall
' instalamos la versión 356
installOrUninstall InstallUID, DistrFolder + "8.2.9.356\setup\1CEnterprise 8.2.msi", "1049.mst", requiredInstall

<< Prev Next >>